home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
LOGIC Apps
/
Logic-APPLE_II_APPS.iso
/
mac
/
LOGIC Apple II 5.25" Library - ProDOS
/
PRO050.dsk
/
BASIC.COPY.bas
< prev
next >
Wrap
BASIC Source File
|
2012-02-16
|
2KB
|
48 lines
10 REM *** BASIC.COPY *** (ProDos Inside & Out p.77)
20 HOME
25 A$ = " ": HTAB 9: VTAB 8: INVERSE
30 FOR I = 1 TO 25: PRINT A$;: NEXT : PRINT
35 FOR I = 1 TO 8: HTAB 9: PRINT A$;: HTAB 33: PRINT A$: NEXT
40 HTAB 9: VTAB 16
45 FOR I = 1 TO 25: PRINT A$;: NEXT : PRINT : NORMAL
50 HTAB 16: VTAB 10: PRINT "CheckWriter"
55 HTAB 20: VTAB 12: PRINT "by"
60 HTAB 14: VTAB 14: PRINT "Howard R. Cohen"
70 HTAB 24: VTAB 15: PRINT "(c) 1987
100 D$ = CHR$(4)
110 P1$ = PP$: REM prefix of volume that files are to be copied FROM
120 P2$ = "/RAM/": REM prefix of volume that files are to be copied TO
130 F$ = "CW":T$ = "BAS": GOSUB 400: REM file to copy
140 F$ = "LP":T$ = "BAS": GOSUB 400
150 F$ = "RPT":T$ = "BAS": GOSUB 400
160 F$ = "CAT":T$ = "BAS": GOSUB 400
170 F$ = "BAL":T$ = "BAS": GOSUB 400
175 F$ = "CALC":T$ = "BAS": GOSUB 400
180 F$ = "BUD":T$ = "BAS": GOSUB 400
190 F$ = "DATA.SAVER":T$ = "BAS": GOSUB 400
200 F$ = "BASIC.COPY.2":T$ = "BAS": GOSUB 400
210 F$ = "DATA.LOC":T$ = "TXT": GOSUB 400
290 PRINT D$;"RUN /RAM/BASIC.COPY.2": REM next program to run
300 END
400 B = 0:A = 0:E = 0:L = 0: REM Important--messing with this line can be fatal
405 X1 = 0:X2 = 0:CMD = 0
410 PRINT D$;"FRE"
420 A = PEEK(109) + PEEK(110) *256
425 E = PEEK(111) + PEEK(112) *256
430 ONERR GOTO 500
440 PRINT D$;"CREATE";P2$;F$;",T";T$
450 PRINT D$;"BLOAD";P1$;F$;",T";T$;",A";A;",E";E -1;",B";B
455 CMD = 196: GOSUB 600:X1 = PEEK(48825):X2 = PEEK(48826)
460 L = PEEK(48859) + PEEK(48860) *256
470 PRINT D$;"BSAVE";P2$;F$;",T";T$;",A";A;",L";L;",B";B
475 CMD = 195: POKE 48820,7: POKE 48825,X1: POKE 48826,X2: GOSUB 600
480 IF L = (E -A) THEN B = B +L: GOTO 450
490 POKE 216,0: RETURN
500 IF PEEK(222) = 19 THEN PRINT D$;"DELETE";P2$;F$: RESUME
510 IF PEEK(222) = 5 THEN CALL -3288: GOTO 490
520 PRINT "ERROR #"; PEEK(222);" IN LINE "; PEEK(218) + PEEK(219) *256
530 END
600 REM *** MLI caller for use with BASIC.SYSTEM ***
610 POKE 48728,169: POKE 48729,CMD: POKE 48730,32
620 POKE 48731,112: POKE 48732,190: POKE 48733,176
630 POKE 48734,170: POKE 48735,96: CALL 48728: RETURN