home *** CD-ROM | disk | FTP | other *** search
/ LOGIC Apps / Logic-APPLE_II_APPS.iso / mac / LOGIC Apple II 5.25" Library - ProDOS / PRO050.dsk / BASIC.COPY.bas < prev    next >
BASIC Source File  |  2012-02-16  |  2KB  |  48 lines
  1. 10  REM  ***  BASIC.COPY  *** (ProDos Inside & Out p.77)
  2. 20  HOME 
  3. 25 A$ = " ": HTAB 9: VTAB 8: INVERSE 
  4. 30  FOR I = 1 TO 25: PRINT A$;: NEXT : PRINT 
  5. 35  FOR I = 1 TO 8: HTAB 9: PRINT A$;: HTAB 33: PRINT A$: NEXT 
  6. 40  HTAB 9: VTAB 16
  7. 45  FOR I = 1 TO 25: PRINT A$;: NEXT : PRINT : NORMAL 
  8. 50  HTAB 16: VTAB 10: PRINT "CheckWriter"
  9. 55  HTAB 20: VTAB 12: PRINT "by"
  10. 60  HTAB 14: VTAB 14: PRINT "Howard R. Cohen"
  11. 70  HTAB 24: VTAB 15: PRINT "(c) 1987
  12. 100 D$ =  CHR$(4)
  13. 110 P1$ = PP$: REM  prefix of volume that files are to be copied FROM
  14. 120 P2$ = "/RAM/": REM  prefix of volume that files are to be copied TO
  15. 130 F$ = "CW":T$ = "BAS": GOSUB 400: REM  file to copy
  16. 140 F$ = "LP":T$ = "BAS": GOSUB 400
  17. 150 F$ = "RPT":T$ = "BAS": GOSUB 400
  18. 160 F$ = "CAT":T$ = "BAS": GOSUB 400
  19. 170 F$ = "BAL":T$ = "BAS": GOSUB 400
  20. 175 F$ = "CALC":T$ = "BAS": GOSUB 400
  21. 180 F$ = "BUD":T$ = "BAS": GOSUB 400
  22. 190 F$ = "DATA.SAVER":T$ = "BAS": GOSUB 400
  23. 200 F$ = "BASIC.COPY.2":T$ = "BAS": GOSUB 400
  24. 210 F$ = "DATA.LOC":T$ = "TXT": GOSUB 400
  25. 290  PRINT D$;"RUN /RAM/BASIC.COPY.2": REM  next program to run
  26. 300  END 
  27. 400 B = 0:A = 0:E = 0:L = 0: REM  Important--messing with this line can be fatal
  28. 405 X1 = 0:X2 = 0:CMD = 0
  29. 410  PRINT D$;"FRE"
  30. 420 A =  PEEK(109) + PEEK(110) *256
  31. 425 E =  PEEK(111) + PEEK(112) *256
  32. 430  ONERR  GOTO 500
  33. 440  PRINT D$;"CREATE";P2$;F$;",T";T$
  34. 450  PRINT D$;"BLOAD";P1$;F$;",T";T$;",A";A;",E";E -1;",B";B
  35. 455 CMD = 196: GOSUB 600:X1 =  PEEK(48825):X2 =  PEEK(48826)
  36. 460 L =  PEEK(48859) + PEEK(48860) *256
  37. 470  PRINT D$;"BSAVE";P2$;F$;",T";T$;",A";A;",L";L;",B";B
  38. 475 CMD = 195: POKE 48820,7: POKE 48825,X1: POKE 48826,X2: GOSUB 600
  39. 480  IF L = (E -A)  THEN B = B +L: GOTO 450
  40. 490  POKE 216,0: RETURN 
  41. 500  IF  PEEK(222) = 19  THEN  PRINT D$;"DELETE";P2$;F$: RESUME 
  42. 510  IF  PEEK(222) = 5  THEN  CALL  -3288: GOTO 490
  43. 520  PRINT "ERROR #"; PEEK(222);" IN LINE "; PEEK(218) + PEEK(219) *256
  44. 530  END 
  45. 600  REM  *** MLI caller for use with BASIC.SYSTEM ***
  46. 610  POKE 48728,169: POKE 48729,CMD: POKE 48730,32
  47. 620  POKE 48731,112: POKE 48732,190: POKE 48733,176
  48. 630  POKE 48734,170: POKE 48735,96: CALL 48728: RETURN